[build] Use custom target for python package building

CMakeLists.txt

@@ -216,23 +216,6 @@ if(BUDDY_MLIR_ENABLE_RISCV_GNU_TOOLCHAIN)
   )
 endif()
 
-#-------------------------------------------------------------------------------
-# Initialize Python packages
-#-------------------------------------------------------------------------------
-if(BUDDY_MLIR_ENABLE_PYTHON_PACKAGES)
-  # Find the Python interpreter and development components,
-  # requiring a minimum version of 3.10
-  find_package(Python3 3.10 REQUIRED COMPONENTS Interpreter Development)
-  # Create directories for the BUDDY-MLIR Python packages
-  file(MAKE_DIRECTORY ${BUDDY_MLIR_PYTHON_PACKAGES_DIR}/buddy)
-  file(MAKE_DIRECTORY ${BUDDY_MLIR_PYTHON_PACKAGES_DIR}/buddy/compiler)
-  # Create empty __init__.py files to make these directories Python packages
-  file(WRITE ${BUDDY_MLIR_PYTHON_PACKAGES_DIR}/buddy/__init__.py "")
-  file(WRITE ${BUDDY_MLIR_PYTHON_PACKAGES_DIR}/buddy/compiler/__init__.py "")
-
-  install(DIRECTORY ${BUDDY_MLIR_PYTHON_PACKAGES_DIR}/buddy DESTINATION python_packages)
-endif()
-
 #-------------------------------------------------------------------------------
 # Directory setup
 #-------------------------------------------------------------------------------

examples/CMakeLists.txt

@@ -62,8 +62,8 @@ set(BUDDY_EXAMPLES_DEPENDS
   mlir-runner
   )
 
-if(BUDDY_MLIR_ENABLE_PYTHON_PACKAGES)
-  list(APPEND BUDDY_TEST_DEPENDS BuddyMLIRPythonModules)
+if(BUDDY_MLIR_ENABLE_PYTHON_PACKAGES AND MLIR_ENABLE_BINDINGS_PYTHON)
+  list(APPEND BUDDY_TEST_DEPENDS python-package-buddy-mlir)
 endif()
 
 add_lit_testsuite(check-examples "Checking the buddy-mlir examples..."

frontend/Python/CMakeLists.txt

@@ -1,11 +1,39 @@
+# Find the Python interpreter and module development components,
+# requiring a minimum version of 3.10
+find_package(Python3 ${LLVM_MINIMUM_PYTHON_VERSION} REQUIRED COMPONENTS Interpreter Development.Module)
+
+set(BUDDY_MLIR_PYTHON_PACKAGES_DIR ${CMAKE_BINARY_DIR}/python_packages)
+
+# Create directories for the BUDDY-MLIR Python packages
+file(MAKE_DIRECTORY ${BUDDY_MLIR_PYTHON_PACKAGES_DIR}/buddy)
+file(MAKE_DIRECTORY ${BUDDY_MLIR_PYTHON_PACKAGES_DIR}/buddy/compiler)
+# Create empty __init__.py files to make these directories Python packages
+file(WRITE ${BUDDY_MLIR_PYTHON_PACKAGES_DIR}/buddy/__init__.py "")
+file(WRITE ${BUDDY_MLIR_PYTHON_PACKAGES_DIR}/buddy/compiler/__init__.py "")
+
 # Recursively retrieve all python files from the current directory.
 file(GLOB_RECURSE ALL_PY_FILES RELATIVE "${CMAKE_CURRENT_SOURCE_DIR}" "*.py")
 
+set(PYTHON_OUTPUT_FILES "")
 foreach(FILE ${ALL_PY_FILES})
-    # Get the directory of the current file.
-    get_filename_component(DIR "${FILE}" DIRECTORY)
-    # Set the destination directory for the target file.
-    set(DEST "${BUDDY_MLIR_PYTHON_PACKAGES_DIR}/buddy/compiler/${DIR}")
-    # Copy the file into the destination directory.
-    file(COPY ${FILE} DESTINATION ${DEST})
+    get_filename_component(REL_DIR "${FILE}" DIRECTORY)
+    set(SRC "${CMAKE_CURRENT_SOURCE_DIR}/${FILE}")
+    set(DEST_DIR "${BUDDY_MLIR_PYTHON_PACKAGES_DIR}/buddy/compiler/${REL_DIR}")
+    set(DEST_FILE "${BUDDY_MLIR_PYTHON_PACKAGES_DIR}/buddy/compiler/${FILE}")
+
+    add_custom_command(
+        OUTPUT "${DEST_FILE}"
+        COMMAND ${CMAKE_COMMAND} -E make_directory "${DEST_DIR}"
+        COMMAND ${CMAKE_COMMAND} -E copy_if_different "${SRC}" "${DEST_FILE}"
+        DEPENDS "${SRC}"
+        COMMENT "Syncing ${FILE}"
+        VERBATIM
+    )
+
+    list(APPEND PYTHON_OUTPUT_FILES "${DEST_FILE}")
 endforeach()
+
+add_custom_target(python-package-buddy
+    ALL DEPENDS ${PYTHON_OUTPUT_FILES}
+    COMMENT "Syncing python package files"
+)

midend/python/CMakeLists.txt

@@ -130,3 +130,5 @@ add_mlir_python_modules(BuddyMLIRPythonModules
     BuddyMLIRPythonCAPI
     MLIRPythonCAPI
   )
+
+add_custom_target(python-package-buddy-mlir DEPENDS BuddyMLIRPythonModules)

tests/CMakeLists.txt

@@ -29,7 +29,7 @@ if(BUDDY_MLIR_ENABLE_DIP_LIB)
 endif()
 
 if(BUDDY_MLIR_ENABLE_PYTHON_PACKAGES)
-  list(APPEND BUDDY_TEST_DEPENDS BuddyMLIRPythonModules)
+  list(APPEND BUDDY_TEST_DEPENDS python-package-buddy-mlir)
 endif()
 
 add_lit_testsuite(check-tests "Running the buddy regression tests..."
@@ -59,6 +59,7 @@ if(BUDDY_ENABLE_E2E_TESTS)
   buddy-translate
   mlir-runner
   buddy-lenet-run-test-cpu
+  python-package-buddy
   )
 
   add_lit_testsuite(check-e2e "Running E2E tests for Models directory..."