build.gradle

plugins {
	id 'java'
	id 'org.springframework.boot' version '3.2.5' apply(false)
	id 'io.spring.dependency-management' version '1.1.4'
	id 'maven-publish'
}

group = 'com.querydslitemreader'
version = '1.0.1'

configurations {
	compileOnly {
		extendsFrom annotationProcessor
	}
}

java {
	sourceCompatibility = '17'
}

repositories {
	mavenCentral()
	maven { url "https://jitpack.io" }
}

dependencyManagement {
	imports {
		mavenBom org.springframework.boot.gradle.plugin.SpringBootPlugin.BOM_COORDINATES
	}
}

dependencies {
	compileOnly 'org.projectlombok:lombok'
	annotationProcessor 'org.projectlombok:lombok'
	implementation 'org.springframework.boot:spring-boot-starter-batch'
	implementation 'org.springframework.boot:spring-boot-starter-data-jpa'
	testImplementation 'org.springframework.boot:spring-boot-starter-test'
	testImplementation 'org.springframework.batch:spring-batch-test'
	testRuntimeOnly 'org.junit.platform:junit-platform-launcher'

	// Spring boot 3.x이상에서 QueryDsl 패키지를 정의하는 방법
	implementation 'com.querydsl:querydsl-jpa:5.0.0:jakarta'
	annotationProcessor "com.querydsl:querydsl-apt:5.0.0:jakarta"
	annotationProcessor "jakarta.annotation:jakarta.annotation-api"
	annotationProcessor "jakarta.persistence:jakarta.persistence-api"
}

publishing {
	publications {
		maven(MavenPublication) {
			groupId = 'com.querydslitemreader.core'
			artifactId = 'pagingitemreader'
			from components.java
			versionMapping {
				usage('java-runtime') {
					fromResolutionResult()
				}
			}
		}
	}
}

tasks.named('test') {
	useJUnitPlatform()
}