Extension.v3

// Copyright 2019 Ben L. Titzer. All rights reserved.
// See LICENSE for details of Apache 2.0 license.

// Extensions that enable various features of the engine.
enum Extension(short_name: string, help: string) {
	TAIL_CALL("tail-call", "Tail calls"),
	MULTI_MEMORY("multi-memory", "Multiple memories"),
	FUNCTION_REFERENCES("function-references", "Typed function references"),
	ATOMICS("threads", "Atomic operations"),
	GC("gc", "Garbage collection"),
	EXCEPTION_HANDLING("exception-handling", "Exception handling"),
	LEGACY_EH("legacy-eh", "Non-standard legacy exception handling"),
	MEMORY64("memory64", "64-bit memories"),
	REPEAT_SECTIONS("repeat-sections", "Repeated sections and relaxed order"),
	STACK_SWITCHING("stack-switching", "Stack switching"),
	CUSTOM_PAGE_SIZES("custom-page-sizes", "Custom page sizes"),
	EXTENDED_CONST("extended-const", "Extended constant expressions"),
	RELAXED_SIMD("relaxed-simd", "Relaxed SIMD"),
	WASM_3_0("wasm-3.0", "All Wasm 3.0 features"),
	WIZENG("wizeng", "Wizard-specific engine capabilities"),
}
component Extensions {
	def getDefaults() -> Extension.set {
		return setImplications(Extension.WASM_3_0);
	}
	def setImplications(set: Extension.set) -> Extension.set {
		if (set.WASM_3_0) {
			set |= Extension.MULTI_MEMORY;
			set |= Extension.TAIL_CALL;
			set |= Extension.FUNCTION_REFERENCES;
			set |= Extension.GC;
			set |= Extension.EXCEPTION_HANDLING;
			set |= Extension.EXTENDED_CONST;
			set |= Extension.RELAXED_SIMD;
			set |= Extension.MEMORY64;
		}
		if (set.STACK_SWITCHING) {
			set |= Extension.GC;
			set |= Extension.EXCEPTION_HANDLING;
		}
		if (set.MEMORY64) {
			set |= Extension.MULTI_MEMORY;
			set |= Extension.EXTENDED_CONST;
			set |= Extension.GC;
			set |= Extension.EXCEPTION_HANDLING;
		}
		if (set.CUSTOM_PAGE_SIZES) {
			set |= Extension.MULTI_MEMORY;
			set |= Extension.MEMORY64;
			set |= Extension.EXCEPTION_HANDLING;
			set |= Extension.EXTENDED_CONST;
		}
		if (set.GC) set |= Extension.FUNCTION_REFERENCES;
		if (set.FUNCTION_REFERENCES) set |= Extension.TAIL_CALL;
		if (set.EXCEPTION_HANDLING) set |= Extension.TAIL_CALL;
		return set;
	}
}