[asan] Sanitize all executables defined in ROOT's build system.

Instead of sanitizing only a few hand-picked executables, recursively
search all executables defined in the build system. Sanitize all that
don't link to ROOTStaticSanitizerConfig.

Since roottest is part of ROOT, several special cases could be removed.

Author: hageboeck

CMakeLists.txt

@@ -729,6 +729,28 @@ if(LLVM_LINKER_IS_MOLD)
   endif()
 endif()
 
+if(asan)
+  # Now sanitize all executables that are not created with ROOT_EXECUTABLE()
+  # See core/sanitizer for details
+  function(sanitize_all_targets DIR_TO_SEARCH)
+    get_property(subdirs DIRECTORY "${DIR_TO_SEARCH}" PROPERTY SUBDIRECTORIES)
+    foreach(subdir IN LISTS subdirs)
+      sanitize_all_targets("${subdir}")
+    endforeach()
+
+    get_directory_property(directory_targets DIRECTORY "${DIR_TO_SEARCH}" BUILDSYSTEM_TARGETS)
+    foreach(target IN LISTS directory_targets)
+      get_target_property(target_type ${target} TYPE)
+      get_target_property(target_libs ${target} LINK_LIBRARIES)
+      if(target_type STREQUAL EXECUTABLE AND NOT target STREQUAL ROOTStaticSanitizerConfig AND NOT target_libs MATCHES "ROOTStaticSanitizerConfig")
+        target_link_libraries(${target} PRIVATE ROOTStaticSanitizerConfig)
+        message(VERBOSE "Adding sanitizer library to ${target} (not created via a ROOT macro): ${target_libs}")
+      endif()
+    endforeach()
+  endfunction()
+  sanitize_all_targets(${CMAKE_CURRENT_SOURCE_DIR})
+endif()
+
 cmake_host_system_information(RESULT PROCESSOR QUERY PROCESSOR_DESCRIPTION)
 
 message(STATUS "ROOT Configuration \n

cmake/modules/RootMacros.cmake

@@ -1477,9 +1477,9 @@ function(ROOT_EXECUTABLE executable)
       endif()
     endforeach()
   endif()
-  if(TARGET ROOT::ROOTStaticSanitizerConfig)
+  if(TARGET ROOTStaticSanitizerConfig)
     set_property(TARGET ${executable}
-      APPEND PROPERTY LINK_LIBRARIES ROOT::ROOTStaticSanitizerConfig)
+      APPEND PROPERTY LINK_LIBRARIES ROOTStaticSanitizerConfig)
   endif()
   #----Installation details------------------------------------------------------
   if(NOT ARG_NOINSTALL AND CMAKE_RUNTIME_OUTPUT_DIRECTORY)
@@ -2872,19 +2872,13 @@ macro(ROOTTEST_GENERATE_EXECUTABLE executable)
           set(libraries ${libraries} ${library})
         endif()
       endforeach()
-      target_link_libraries(${executable} ${libraries})
+      target_link_libraries(${executable} PUBLIC ${libraries})
     else()
-      target_link_libraries(${executable} ${ARG_LIBRARIES})
+      target_link_libraries(${executable} PUBLIC ${ARG_LIBRARIES})
     endif()
   endif()
-  if(MSVC AND DEFINED ROOT_SOURCE_DIR)
-    if(TARGET ROOTStaticSanitizerConfig)
-      target_link_libraries(${executable} ROOTStaticSanitizerConfig)
-    endif()
-  else()
-    if(TARGET ROOT::ROOTStaticSanitizerConfig)
-      target_link_libraries(${executable} ROOT::ROOTStaticSanitizerConfig)
-    endif()
+  if(TARGET ROOTStaticSanitizerConfig)
+    target_link_libraries(${executable} PRIVATE ROOTStaticSanitizerConfig)
   endif()
 
   if(ARG_COMPILE_FLAGS)
@@ -3493,14 +3487,8 @@ function(ROOTTEST_ADD_UNITTEST_DIR)
   target_link_libraries(${binary} PRIVATE GTest::gtest GTest::gtest_main ${libraries})
   set_property(TARGET ${binary} PROPERTY BUILD_WITH_INSTALL_RPATH OFF) # will never be installed anyway
 
-  if(MSVC AND DEFINED ROOT_SOURCE_DIR)
-    if(TARGET ROOTStaticSanitizerConfig)
-      target_link_libraries(${binary} ROOTStaticSanitizerConfig)
-    endif()
-  else()
-    if(TARGET ROOT::ROOTStaticSanitizerConfig)
-      target_link_libraries(${binary} PRIVATE ROOT::ROOTStaticSanitizerConfig)
-    endif()
+  if(TARGET ROOTStaticSanitizerConfig)
+    target_link_libraries(${binary} PRIVATE ROOTStaticSanitizerConfig)
   endif()
 
   # Mark the test as known to fail.

core/sanitizer/CMakeLists.txt

@@ -18,10 +18,3 @@ target_link_libraries(${library} INTERFACE ${ASAN_EXTRA_EXE_LINKER_FLAGS})
 # Make it visible to the outside to sanitize e.g. roottest executables
 set_property(GLOBAL APPEND PROPERTY ROOT_EXPORTED_TARGETS ${library})
 add_library(ROOT::${library} ALIAS ${library})
-
-# Now sanitize executables that are not created with ROOT_EXECUTABLE():
-foreach(target llvm-min-tblgen llvm-tblgen clang-tblgen cppinterop-tblgen)
-  if(TARGET ${target})
-    target_link_libraries(${target} PRIVATE ${library})
-  endif()
-endforeach()