Several clicks not handled properly

[LouisePla]

If we click several times quickly, only one click out of two is taken into account.
We need a way to take every click into account.

Example :

| b |
b := BlElement new extent: 50 asPoint.
b background: Color random.
b addEventHandlerOn: BlClickEvent do: [ :e | Transcript crShow: 'Hello' ].
b openInSpace 

[plantec]

@tinchodias I've tried the following:
b eventDispatcher disableEventType: BlDoubleClickEvent.

It doesn't work and I don't know how it can works since BlElementEventDispatcher>>disableEventType: is broken.
It doesn't work event after a simple fixe because the #activatedGeneralEvents inst var is not used to check the event type on event dispatching AFAIK

[plantec]

anyway, I think it should be managed at the BlMouseProcessor level.
The element should be asked with a #wantsDoubleClick or something like that.
It should be false by default

[tinchodias]

I've found a workaround that can serve to find a proper solution:

BlMouseProcessor >>
processMouseUp: aMouseUpEvent

	self fireEvent: aMouseUpEvent.

	self updateCursorFrom: aMouseUpEvent target.

	(self canBeClickEvent: aMouseUpEvent)
		ifTrue: [
			|  consumed |
			consumed := false.
			(self canBeDblClickEvent: aMouseUpEvent) ifTrue: [
				consumed := (self fireEvent: aMouseUpEvent asDoubleClickEvent) currentTarget ~= space root ].

			consumed ifFalse: [ self fireClickEventFrom: aMouseUpEvent ] ]
		ifFalse: [ 
			(self canBeClickAbortedEvent: aMouseUpEvent) ifTrue: [
				self fireClickAbortedEventFrom: aMouseUpEvent ] ]

BlEvent has a consumed boolean flag, that we could check instead of comparing with the root. That would mean that all handlers of double click event MUST consume the event in the handler. Drag and drop uses this flag to notify Bloc that a drag started.

[tinchodias]

As a reference, I've looked at Roassal, and has the same issue, the double clicks that are not handled are not dispatched as 2 separated single clicks.
Script:

b := RSBox new.
b extent: 100 @ 100.
count := 0.
b when: RSMouseLeftClick do: [ count := count + 1. count traceCr ] for: self.

c := RSCanvas new.
c addShape: b.
c open

[tinchodias]

This Morphic button DOESN'T have the issue: each click increases the counter:

count := 0.
morph := SimpleButtonMorph new
	label: 'COUNT';
	target: [
		count := count + 1.
		count traceCr ];
	actionSelector: #value;
	yourself.
morph openInWindow.

[tinchodias]

However, that was for the SimpleButtonMorph. Instead, the general Morph event handler behaves the same way as Bloc and Roassal. Check with:

count := 0.
count2 := 0.
morph := Morph new
	on: #click send: #value to: [
		#click trace.
		count := count + 1.
		count traceCr ];
	yourself.
morph openInWindow.

Additional note:
This is how a Morph handles several fast clicks when there are handlers for both click and double-click:

  First click is always a click, but second is considered a double-click (the timeout is 350ms by default).

Code:

count := 0.
count2 := 0.
morph := Morph new
	on: #click send: #value to: [
		#click trace.
		count := count + 1.
		count traceCr ];
	on: #doubleClick send: #value to: [
		#doubleClick trace.
		count2 := count2 + 1.
		count2 traceCr ];
	yourself.
morph openInWindow.

you get:

click1
doubleClick1
click2
doubleClick2
click3
doubleClick3
click4
doubleClick4
click5
doubleClick5