invalid '-' stata(): 3598 Stata returned error

[amedenthusiast]

Hi, I am working on bootstrap internal validation using Stata. I had developed these programs few months ago and tried running it again earlier this week, but I encountered [CODE]r(3598)[/CODE] error.

Please find the programs here:

*===============================================================================
* PROGRAM 1: Forward Selection using QIC
* Returns: selected variables as local macro
*===============================================================================
capture program drop forward_select_qic
program define forward_select_qic, rclass
    syntax varlist(min=1), outcome(varname) [penter(real 0.10)]
    
    local candidates `varlist'
    local selected ""
    local best_qic = .
    local keep_adding = 1
    
    *---------------------------------------------------------------------------
    * Step 1: Univariable screening (p < penter)
    *---------------------------------------------------------------------------
    local candidates_pass ""
    foreach var of local candidates {
        capture quietly xtgee `outcome' `var', ///
            family(binomial) link(logit) corr(exchangeable) robust
        
        if _rc == 0 {
            local pval = 2*normal(-abs(_b[`var']/_se[`var']))
            if `pval' < `penter' {
                local candidates_pass `candidates_pass' `var'
            }
        }
    }
    
    if "`candidates_pass'" == "" {
        return local selected ""
        exit
    }
    
    *---------------------------------------------------------------------------
    * Step 2: Forward selection based on QIC + p<0.05
    *---------------------------------------------------------------------------
    local remaining `candidates_pass'
    
    while `keep_adding' {
        local var_to_add = ""
        local new_best_qic = .
        local improved = 0
        
        * Try adding each remaining variable
        foreach var of local remaining {
            local test_vars `selected' `var'
            
            capture quietly qic `outcome' `test_vars', ///
                family(binomial) link(logit) corr(exchangeable) robust
            
            if _rc == 0 {
                local current_qic = r(qic)
                
                * Check if the new variable has p<0.05
                capture quietly xtgee `outcome' `test_vars', ///
                    family(binomial) link(logit) corr(exchangeable) robust
                
                if _rc == 0 {
                    local pval_new = 2*normal(-abs(_b[`var']/_se[`var']))
                    
                    * Variable must have p<0.05
                    if `pval_new' < 0.05 {
                        * For first variable: find lowest QIC among all candidates
                        * For subsequent: only add if QIC improves
                        if "`selected'" == "" {
                            * First variable: select one with lowest QIC
                            if `new_best_qic' == . | `current_qic' < `new_best_qic' {
                                local new_best_qic = `current_qic'
                                local var_to_add = "`var'"
                                local improved = 1
                            }
                        }
                        else {
                            * Subsequent variables: must improve current best QIC
                            if `current_qic' < `best_qic' {
                                if `new_best_qic' == . | `current_qic' < `new_best_qic' {
                                    local new_best_qic = `current_qic'
                                    local var_to_add = "`var'"
                                    local improved = 1
                                }
                            }
                        }
                    }
                }
            }
        }
        
        * Add variable if improvement found
        if `improved' {
            local selected `selected' `var_to_add'
            local remaining : list remaining - var_to_add
            local best_qic = `new_best_qic'
            
            * Stop if no more candidates
            if "`remaining'" == "" {
                local keep_adding = 0
            }
        }
        else {
            * No improvement possible
            local keep_adding = 0
        }
    }
    
    return local selected "`selected'"
end

*===============================================================================
* PROGRAM 2: Bootstrap Internal Validation (Box 2)
* Follows the exact steps from Box 2
*===============================================================================
capture program drop boot_internal_validation
program define boot_internal_validation, rclass
    version 16.0
    syntax , reps(integer) [penter(real 0.10)]
    
    display as text "{hline 80}"
    display as text "Bootstrap Internal Validation (Following Box 2)"
    display as text "{hline 80}"
    display as text "Outcome: $outcome_var"
    display as text "Candidate predictors: " _c
    local n_cand : word count $candidates
    display as result `n_cand'
    display as text "Bootstrap replications: " as result `reps'
    display as text "Univariable screening: p<" as result `penter'
    display as text "Selection method: Forward selection by QIC (p<0.05 required)"
    display as text "{hline 80}" _newline
    
    preserve
    
    *---------------------------------------------------------------------------
    * STEP 1: Develop model on original data (apparent performance)
    *---------------------------------------------------------------------------
    display as text "STEP 1: Developing model on original dataset..."
    
    quietly xtset $cluster_id visit_number
    forward_select_qic $candidates, outcome($outcome_var) penter(`penter')
    local original_selected = r(selected)
    
    if "`original_selected'" == "" {
        display as error "No variables selected on original data!"
        display as text "Try increasing penter threshold or checking your data"
        restore
        exit
    }
    
    display as text "Selected variables: " as result "`original_selected'"
    
    * Fit final model on original data
    quietly xtgee $outcome_var `original_selected', ///
        family(binomial) link(logit) corr(exchangeable) robust
    
    predict xb_apparent, xb
    quietly roctab $outcome_var xb_apparent
    scalar auc_apparent = r(area)
    
    quietly logit $outcome_var xb_apparent, vce(cluster $cluster_id)
    scalar slope_apparent = _b[xb_apparent]
    drop xb_apparent
    
    display as text "  Apparent AUC: " as result %5.3f auc_apparent
    display as text "  Apparent Calibration Slope: " as result %5.3f slope_apparent
    display as text "{hline 80}" _newline
    
    *---------------------------------------------------------------------------
    * Initialize tracking matrices
    *---------------------------------------------------------------------------
    local n_candidates : word count $candidates
    tempname selection_matrix corrected_aucs corrected_slopes
    matrix `selection_matrix' = J(`reps', `n_candidates', 0)
    matrix `corrected_aucs' = J(`reps', 1, .)
    matrix `corrected_slopes' = J(`reps', 1, .)
    
    *---------------------------------------------------------------------------
    * STEPS 2-5: Bootstrap loop
    *---------------------------------------------------------------------------
    display as text "STEPS 2-5: Bootstrap resampling and optimism calculation..."
    
    tempname total_optimism_auc total_optimism_slope
    scalar `total_optimism_auc' = 0
    scalar `total_optimism_slope' = 0
    local successful = 0
    
    forvalues rep = 1/`reps' {
        if mod(`rep', 10) == 0 {
            display as text "  Bootstrap iteration `rep'/`reps' - " _c
            display as result %3.0f (`rep'/`reps'*100) as text "% complete"
        }
        
        restore, preserve
        
        capture noisily {
            *-------------------------------------------------------------------
            * STEP 2: Generate bootstrap sample
            *-------------------------------------------------------------------
            quietly bsample, cluster($cluster_id)
            
            * Create new sequential time index to avoid duplicates
            quietly bysort $cluster_id: gen _boot_time = _n
            quietly xtset $cluster_id _boot_time
            
            *-------------------------------------------------------------------
            * STEP 3: Develop bootstrap model (same methods as original)
            *-------------------------------------------------------------------
            forward_select_qic $candidates, outcome($outcome_var) penter(`penter')
            local boot_selected = r(selected)
            
            * Track which variables were selected
            if "`boot_selected'" != "" {
                local col = 1
                foreach var of global candidates {
                    local is_selected : list var in boot_selected
                    if `is_selected' {
                        matrix `selection_matrix'[`rep', `col'] = 1
                    }
                    local col = `col' + 1
                }
                
                *---------------------------------------------------------------
                * STEP 3a: Bootstrap performance (in bootstrap sample)
                *---------------------------------------------------------------
                quietly {
                    xtgee $outcome_var `boot_selected', ///
                        family(binomial) link(logit) corr(exchangeable) robust
                    predict xb_boot, xb
                    roctab $outcome_var xb_boot
                    local auc_boot = r(area)
                    logit $outcome_var xb_boot, vce(cluster $cluster_id)
                    local slope_boot = _b[xb_boot]
                    drop xb_boot _boot_time
                }
                
                *---------------------------------------------------------------
                * STEP 3b: Test performance (in original data)
                *---------------------------------------------------------------
                restore, preserve
                quietly {
                    xtset $cluster_id visit_number
                    xtgee $outcome_var `boot_selected', ///
                        family(binomial) link(logit) corr(exchangeable) robust
                    predict xb_test, xb
                    roctab $outcome_var xb_test
                    local auc_test = r(area)
                    logit $outcome_var xb_test, vce(cluster $cluster_id)
                    local slope_test = _b[xb_test]
                    drop xb_test
                }
                
                *---------------------------------------------------------------
                * STEP 4: Calculate optimism
                *---------------------------------------------------------------
                local optimism_auc = `auc_boot' - `auc_test'
                local optimism_slope = `slope_boot' - `slope_test'
                
                scalar `total_optimism_auc' = `total_optimism_auc' + `optimism_auc'
                scalar `total_optimism_slope' = `total_optimism_slope' + `optimism_slope'
                
                local successful = `successful' + 1
                
                *---------------------------------------------------------------
                * Store corrected values for this iteration
                *---------------------------------------------------------------
                local auc_corrected_i = auc_apparent - `optimism_auc'
                local slope_corrected_i = slope_apparent - `optimism_slope'
                matrix `corrected_aucs'[`rep', 1] = `auc_corrected_i'
                matrix `corrected_slopes'[`rep', 1] = `slope_corrected_i'
            }
        }
        
        if _rc {
            * Skip failed iterations silently
        }
    }
    
    restore
    
    *---------------------------------------------------------------------------
    * STEP 6: Average optimism
    *---------------------------------------------------------------------------
    if `successful' > 0 {
        scalar avg_optimism_auc = `total_optimism_auc' / `successful'
        scalar avg_optimism_slope = `total_optimism_slope' / `successful'
    }
    else {
        display as error "No successful bootstrap iterations!"
        exit
    }
    
    *---------------------------------------------------------------------------
    * STEP 7: Optimism-corrected estimates
    *---------------------------------------------------------------------------
    scalar auc_corrected = auc_apparent - avg_optimism_auc
    scalar slope_corrected = slope_apparent - avg_optimism_slope
    
    *---------------------------------------------------------------------------
    * Calculate 95% CIs from bootstrap distribution
    *---------------------------------------------------------------------------
    preserve
    clear
    svmat `corrected_aucs', names(auc_corr)
    svmat `corrected_slopes', names(slope_corr)
    drop if missing(auc_corr1)
    
    _pctile auc_corr1, p(2.5 97.5)
    scalar auc_ci_lower = r(r1)
    scalar auc_ci_upper = r(r2)
    
    _pctile slope_corr1, p(2.5 97.5)
    scalar slope_ci_lower = r(r1)
    scalar slope_ci_upper = r(r2)
    restore
    
    *---------------------------------------------------------------------------
    * Display results
    *---------------------------------------------------------------------------
    display as text _newline "{hline 80}"
    display as text "RESULTS: Internal Validation"
    display as text "{hline 80}"
    display as text "Original model variables: " as result "`original_selected'"
    display as text "Successful bootstrap iterations: " as result `successful' as text "/" as result `reps'
    display as text "{hline 80}"
    display as text "                          Apparent    Optimism    Corrected"
    display as text "{hline 80}"
    display as text "AUC                   " ///
        as result %9.3f auc_apparent "  " %9.3f avg_optimism_auc "  " %9.3f auc_corrected
    display as text "Calibration Slope     " ///
        as result %9.3f slope_apparent "  " %9.3f avg_optimism_slope "  " %9.3f slope_corrected
    display as text "{hline 80}"
    display as text "AUC (95% CI)          " ///
        as result %9.3f auc_corrected " (" %5.3f auc_ci_lower " - " %5.3f auc_ci_upper ")"
    display as text "Slope (95% CI)        " ///
        as result %9.3f slope_corrected " (" %5.3f slope_ci_lower " - " %5.3f slope_ci_upper ")"
    display as text "{hline 80}" _newline
    
    *---------------------------------------------------------------------------
    * Variable selection frequencies
    *---------------------------------------------------------------------------
    display as text "Variable Selection Frequencies Across Bootstrap Samples"
    display as text "{hline 80}"
    display as text "{col 5}Variable{col 40}Selected (n){col 55}Frequency (%)"
    display as text "{hline 80}"
    
    local col = 1
    foreach var of global candidates {
        local count = 0
        forvalues rep = 1/`reps' {
            local count = `count' + `selection_matrix'[`rep', `col']
        }
        local freq = (`count' / `successful') * 100
        
        if `freq' > 0 {
            display as text "{col 5}`var'{col 40}" as result `count' ///
                as text "{col 55}" as result %5.1f `freq'
        }
        
        local col = `col' + 1
    }
    display as text "{hline 80}"
    
    *---------------------------------------------------------------------------
    * Return results
    *---------------------------------------------------------------------------
    return local original_model "`original_selected'"
    return scalar auc_apparent = auc_apparent
    return scalar auc_corrected = auc_corrected
    return scalar auc_ci_lower = auc_ci_lower
    return scalar auc_ci_upper = auc_ci_upper
    return scalar optimism_auc = avg_optimism_auc
    return scalar slope_apparent = slope_apparent
    return scalar slope_corrected = slope_corrected
    return scalar slope_ci_lower = slope_ci_lower
    return scalar slope_ci_upper = slope_ci_upper
    return scalar optimism_slope = avg_optimism_slope
    return scalar n_successful = `successful'
end
`

Here are the usage example:

webuse airacc, clear

xtset airline time
global cluster_id airline
global candidates relcnt relsize pmiles ait uit
global outcome_var rec

parallel, prog(forward_select_qic): boot_internal_validation, reps(10) penter(0.10)
invalid '-' 
                 stata():  3598  Stata returned error
parallel_export_programs():     -  function returned error
     parallel_write_do():     -  function returned error
                 <istmt>:     -  function returned error
r(3598);

My question:

1. What changed within Stata or parallel over the past few months? The codes had worked perfectly before but it's now returning error?
2. I have checked and there are no en dash or em dashes that might break the loop. I don't know what is wrong.

​​​​​​​Thank you very much in advance.

[bquistorff]

There hasn't been any change to the code for a couple years. Has your setup changed somehow?

When I run your code, the process progresses past that point, but the child processes produces the following errors:

.     boot_internal_validation , reps(10) penter(0.10) 
-------------------------------------------------------------------------------
> -
Bootstrap Internal Validation (Following Box 2)
-------------------------------------------------------------------------------
> -
Outcome: rec
Candidate predictors: 5
Bootstrap replications: 10
Univariable screening: p<.1
Selection method: Forward selection by QIC (p<0.05 required)
-------------------------------------------------------------------------------
> -

STEP 1: Developing model on original dataset...
variable visit_number not found
r(111);

[amedenthusiast]

Not that I'm aware of. Here are the troubleshooting steps that I've taken:

1. Uninstall SCC's parallel using ado uninstall
2. Re-install parallel using the stable release
3. Define the program after parallel initialize

I got past the r(3598) error, but cannot reproduce your steps.

I ended up encountering other errors:
child process 0003 Exited with error -198- while running the command/dofile (view log)...

log entry:

cmd/dofile   : "boot_internal_validation , reps(5000) penter(0.10)"
pll_id       : 3q8bxiozy3
pll_instance : 3/4
tmpdir       : C:\Users\Owner\AppData\Local\Temp/__pll3q8bxiozy3_tmpdir0003/
date-time    : 21:06:47 12 Apr 2026
seed         : XAA0000000000003b82bce46fa75839f3dbb066e4739b758427342c5f9385bf9
> 58467bbcd61c3adc438a97fe6abbb10c50a71addba641599a6e57c2ab27c6f8368a04f262cb1f
> 978b77f27072e73c168cf47daac7d91fa85075e8e7f11c5403b06ffac9612a5807970864289c4
> e6aab01fc58feb84bda4cdc8743416263a2e73d9d4262b4a18602387c3c899be8a52af10a626d
> 9a2498f254d42c4a23fab6a7948422ceae83def69748372b4ae1f34d4fbd7de3f94fa426c74fa
> a4cc3e24016bacd63ecdba3b926877b955b20b8bafd568b27a43a7596332d2f01d4f6a50ac442
> 5ec98c05ceca224ca279de5ca3f1c0576a9638c6758f7472edb61545bdd597c52214ecf5d0121
> 886c04491ee94c6e8efe15c1b55fea3524a822617e2d3caad162a7e01377adcddbb866c3eb7a0
> 0c94efe0f103d5d38323c9b3fe00abe171c8c41738e369a7a93463ac6cd63dbacec3d965f9a98
> 984b879d2be9f1cbc89a0f6ce64b7dadfe62524e21a0319b7b08b9da665cc1d7334950b5aef11
> 826044d0760fab20682df0190d963ff1cf42384b97aa44b4e931b3b67527ad3733a3d63e22caf
> 625e5b93b57fbb772ab18d715f49acd3f8d983df55b8856ef5448885bae07dae00e9d008dadec
> 18c5ff68d295997315da0c3c6109345e7e5f39c5eacfd69857ee44d8cf9a21ec8712ec36c6078
> fa52b949345c935638b92c939638444718282ee58aee0028f6b1616a817b787052b4b4c0766af
> 905f5deef8713c41e6136809db159c6ade7a0ee19639533ca8aad511a378727b4c6312f6ed268
> 434679a307bc31e7e5bf1146a7e8f6bcacd3288bc306c2f2cfec8f08b967305fdf8c73d1b7f82
> f9a99f0c30c0e826d42ab9075e9c29ce89d558914a810c57f774813687465640d5426704c5276
> 71781961ab222b40ad5b49e8a548e29911d3258671d4757e3c6db1c061e7eb0442234aeb2d429
> fd5922bd9f6a05098a8950f9901c6eac33d1c17b644a6aa8151d72f0b0e0614d413a905ac7729
> fac153931175e9f345009ddcbac2eec2c51eab20bae51ba771fd0c2f2d4156249de17548e85bf
> 5da0af1cd028305b4511b3c76dc25508f70f036b897b2e6e3d2f2f1cb0d4ebd73f205f2841a7d
> 4c657a49717e638234dcc84eec1bdc459548c5db84697da2c30ce8ed03556e698f5abaaeb5a60
> d671f3dd6a805031ad54a6ea084fd90fa6a5e61969681e99c6e44449182abd43e022d131aa4f1
> 18c54446c2dcd379757326a891496be8ba16685964d514890788bdd41ce3d40ee2786636bd8b4
> 0be0edd377700ff96fbefc5d16305688955000a07d883bf4cc7f7c95f8dbd0aea35a527a97130
> 90f723786bcce0aff187430f1defa4449141638275213848725b18518b7d0d60ea9f22b21a6ee
> 90d21b884ec57d15211f16642839a319974ccc7f88ff25688df733de313500283a62e59d86d0a
> d7210935662e981ea82e1780a9c466bd11daa4a7acdada19a37b175ba1152ce967bf4f331e558
> bae35f0f966632d8f840f340bc995d20e2f49c1c85191d236ef35a8889cad1890fe6f7f373b3a
> 96e65251be5da98b3b3a239384df1b90b3acb9174e4443dabb7b80a1f0ae987b5ffcf7d8311dc
> 9ac5a77c887825bef9498b5ad206207d77905ca4a83dc7f6f80bc04a1a2b2f32eb4eb1ed25abe
> 342de1c750b15ca441f9e59765ca0a50ef742c0a2263d56399b1a4424faaa201cfb6bfc61e5a7
> 288943b32c5637f45dd9962c91ede27ec8e3ed403218d1eee26fde90a9727a456f64b5b986863
> 8eb69a7297fd40617c08a180d2d6a2fec8c5c8acdbe476d07962598c222e3d13f2c5704316dae
> baef5efd09eb86f9e73556f2b4d80be7928b95c4e8ad132e4ff403054a8551d219e4a6ce3d68b
> e23998bd58af9979559eabf4641c63239c5ba5b9d4283b054d7007f163954a1a2d685c0b6364d
> 1b19420b2aaa41b894407312d68f6c67a9099b6629a44da9d79c38a72db06180bd8c0912d7cdd
> c6709021b1a238d7743c18b94e1b2a893cc68814bab3f689e939265a241bc561a86464baedfc7
> 79652f82cac6b817fb999165706ec33da96567dcb6fc70acc7a2540b139cc29987d2d5706eeec
> 6f81baec853a2340584f33f7d285cce30ee191ab35a298545422285f39b555ec57eb8150f0149
> 9cd78d715d23970f5fd3ec9dd6b92641016dfc2dd807a11a3f3626d89e26c5859b427a42ff1d9
> 7be6c953e04be1e38d94e1461008ad93ff1e3df0c2062e09ff6dd0400c11c4e8b5745d36288a0
> 8f212bdd31cab190665b10b37e6f416aa5b760ec6acc9212f8b20e3fd1e3a3e6b9328f39b1e17
> 44ef1622ef161abb9d02d982b747378279890cb9c5dd9fb245e0d11281807007f44d8265663cf
> 98f8b30189b67d4e6b985012a5e646cc50e66fbda824787fd270dc8d6cec9fa30db3e06802b12
> ae3b8c7a19e39443cc4b74c7af340c41de9eb8fc37a485a8f9fdad0662a45438d7724f2f22780
> 159eb50c93108bd1f3c6dea62d0f6bca577dc489c75c6b690be0b8f1dac7f14e8308f5295f68e
> ac29e9528ea0da7766c474d4918fe295fab2233ea692f7a5d24b096bdcf2782eec579823f4493
> 36add6a43c87fd63ff56b5acf93aa84e6e1f31afb99ec97120dc3ee1e507f99921177df6e946c
> 7cfeef6d707de0bd14ef07ea11692b9fe75b26f544c329c45ab4219cad8236416a31be4940024
> 1c59693bd450709f73cf65d919eba12d0790b2c3def8246e213f0f67ed2e371c1b0a0fe5cdf5d
> 05ce3b76aff1090273821556a5a6773f449581b6b34d2446106c8689918b3d002ea2b4add8fe7
> f4f3d260ccd2deb373eef5af318a866f37a49a1bad107939ee09e5335b260452984065f25fd8f
> a18b96311df01f612de33b9a5c4e4103b0776fc4e1007d03570e649f8c1909133b00a79f12359
> 7fc566f587b787bd56bc97e70f084273f5d7e46a433df8ec7091e92ddb24fd9e3d089c768a20c
> 1131ae5cce225608c429a1429a9c4bcbe9ceec0785095bbe1a8e07383d6e8a9924df25072a407
> e5d241c31f5e6666927ece27a4b43491394296e9202ee4cdb45a1d5e5b97bf52681ecc967fa72
> 4587ccbe09c138f92686ba55fab78f61678690ea72284a0eb9567dcbf3b5f0c750efcd7e51a75
> e8467ce952abd51e26f819f92a615b060df2bd80b6431700a46b34ebb535241fc1bccef22b346
> e2c6fb0902ca0ca71c85b8f07fc76a5f92dcdb9ed0fb4340fd9145f6fe93b98c1dbc27e84112c
> 1939ee108f15cc063652a0a44f069b2ebc5ec0db29706834c14e5851bb14dafc2eac3de1a6592
> 02d088dda4b7229d53974ee60146cf2660c21cf678caf8ac9cd245d7f5424dfb7a50954c19d01
> 32d21cd01a8a77ad1cc4d9fc8fc1bec65998ac58f4e7a666a172312d972cf24532ef65703197e
> 64ead400208cb3eaec2550bb44384ade75bebf8025b64b90a8df33e1fac1f211514346ad4a54b
> 219b673bbe0844626e5b451d666aa46e7670b45f90ecf9b809260b474e37adbb488c2f3100d05
> 0160001000001381851
-------------------------------------------------------------------------------
> -

. local result = _rc

. if (c(rc)) {
. cd "C:\Users\Owner/"
. mata: parallel_write_diagnosis(strofreal(c("rc")),"C:\Users\Owner/__pll3q8bxiozy3_finito0003","while setting memory")
. clear
. exit
. }

. 
. * Loading Programs *
. capture {

. local result = _rc

. if (c(rc)) {
. cd "C:\Users\Owner/"
. mata: parallel_write_diagnosis(strofreal(c("rc")),"C:\Users\Owner/__pll3q8bxiozy3_finito0003","while loading programs")
. clear
. exit
. }

. 
. * Checking for break *
. mata: parallel_break()

. 
. * Loading Globals *
. capture {

. if (c(rc)) {
.   cd "C:\Users\Owner/"
.   mata: parallel_write_diagnosis(strofreal(c("rc")),"C:\Users\Owner/__pll3q8bxiozy3_finito0003","while loading globals")
.   clear
.   exit
. }

. 
. * Checking for break *
. mata: parallel_break()

. capture {
.     use "C:\Users\Owner/__pll3q8bxiozy3_dat
> aset" if _3q8bxiozy3cut == 3
.     drop _3q8bxiozy3cut
. 
. * Checking for break *
. mata: parallel_break()
.     boot_internal_validation , reps(5000) penter(0.10) 
-------------------------------------------------------------------------------
> -
Bootstrap Internal Validation (Following Box 2)
-------------------------------------------------------------------------------
> -
Outcome: test_xpert_algo
Candidate predictors: 13
Bootstrap replications: 5000
Univariable screening: p<.1
Selection method: Forward selection by QIC (p<0.05 required)
-------------------------------------------------------------------------------
> -

STEP 1: Developing model on original dataset...
Selected variables: .
. invalid name
r(198);
.   }

. if (c(rc)) {
.   cd "C:\Users\Owner/
.   mata: parallel_write_diagnosis(strofreal(c("rc")),"C:\Users\Owner/__pll3q8bxiozy3_finito0003","while running the comma
> nd/dofile")
.   clear
.   exit

end of do-file

I tried running the code without parallel and it worked perfectly, so it has something to do with parallel. Perhaps there is something I miss in installing the package?

[amedenthusiast]

Or perhaps could it be because another package that might interfere with how parallel work?

My current packages are:

. ado update

Checking status of installed packages:

    [1] sbe36_2 at http://www.stata-journal.com/software/sj4-4:
        installed package is up to date

    [2] unique at http://fmwww.bc.edu/repec/bocode/u:
        installed package is up to date

    [3] sg97_4 at http://www.stata-journal.com/software/sj12-1:
        package has been updated on server

    [4] cutpt at http://fmwww.bc.edu/RePEc/bocode/c:
        installed package is up to date

    [5] tsegen at http://fmwww.bc.edu/RePEc/bocode/t:
        installed package is up to date

    [6] st0381_1 at http://www.stata-journal.com/software/sj15-2:
        installed package is up to date

    [7] inlist2 at http://fmwww.bc.edu/repec/bocode/i:
        installed package is up to date

    [8] carryforward at http://fmwww.bc.edu/repec/bocode/c:
        installed package is up to date

    [9] qic at http://fmwww.bc.edu/repec/bocode/q:
        installed package is up to date

   [10] missings at http://fmwww.bc.edu/repec/bocode/m:
        installed package is up to date

   [11] coldiag2 at http://fmwww.bc.edu/repec/bocode/c:
        installed package is up to date

   [12] perturb at http://fmwww.bc.edu/repec/bocode/p:
        installed package is up to date

   [13] st0741 at http://www.stata-journal.com/software/sj24-1:
        installed package is up to date

   [14] st0318 at http://www.stata-journal.com/software/sj13-4:
        installed package is up to date

   [15] firthlogit at http://fmwww.bc.edu/RePEc/bocode/f:
        installed package is up to date

   [16] metandi at http://fmwww.bc.edu/repec/bocode/m:
        installed package is up to date

   [17] gllamm at http://fmwww.bc.edu/repec/bocode/g:
        installed package is up to date

   [18] metadta at http://fmwww.bc.edu/repec/bocode/m:
        installed package is up to date

   [19] st0678 at http://www.stata-journal.com/software/sj22-2:
        installed package is up to date

   [20] desctable at https://tdmize.github.io/data:
        installed package is up to date

   [21] st0073_1 at http://www.stata-journal.com/software/sj11-4:
        installed package is up to date

   [22] st0177 at http://www.stata-journal.com/software/sj9-4:
        installed package is up to date

   [23] matchit at http://fmwww.bc.edu/repec/bocode/m:
        installed package is up to date

   [24] estout at http://fmwww.bc.edu/repec/bocode/e:
        package has been updated on server

   [25] summdate at http://fmwww.bc.edu/repec/bocode/s:
        installed package is up to date

   [26] pmcalplot at http://fmwww.bc.edu/RePEc/bocode/p:
        installed package is up to date

   [27] table1 at http://fmwww.bc.edu/RePEc/bocode/t:
        installed package is up to date

   [28] parallel at https://raw.github.com/gvegayon/parallel/stable:
        installed package is up to date

Packages that need to be updated are

    [3] sg97_4       -- SJ12-1 sg97_4.  A new system for formatting estimation...
   [24] estout       -- 'ESTOUT': module to make regression tables

[bquistorff]

We don’t have any dependencies, so it’s likely your code needs something that doesn’t get copied over to the child processes. You can set a trace with sufficient depth in the code that runs in the child process to see what line causes the error. Then see the docs to see how to copy it over. Eg, you may need to copy over more programs using the prog() option.