GameOfLife/CMakeLists.txt at main · fffaraz/GameOfLife · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
cmake_minimum_required(VERSION 3.14)

project(gameoflife LANGUAGES CXX)

set(CMAKE_CXX_STANDARD 20)
set(CMAKE_CXX_STANDARD_REQUIRED ON)
set(CMAKE_POSITION_INDEPENDENT_CODE ON)
set(BUILD_SHARED_LIBS OFF)

# SFML dependencies:
# sudo apt install libxrandr-dev libxcursor-dev libudev-dev libfreetype-dev libopenal-dev libflac-dev libvorbis-dev libgl1-mesa-dev libegl1-mesa-dev
# sudo dnf install freetype-devel libvorbis-devel flac-devel systemd-devel # CSFML-devel

set(SFML_USE_STATIC_STD_LIBS ON)
set(SFML_USE_SYSTEM_DEPS OFF)

set(SDL_SHARED OFF)
set(SDL_STATIC ON)
set(SDL_X11_XSCRNSAVER OFF)
set(SDL_X11_XTEST OFF)

if (NOT MSVC AND CMAKE_BUILD_TYPE STREQUAL "Release")
  set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -O3 -funroll-loops -flto")
  if (WIN32)
    set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -static -static-libgcc -static-libstdc++")
  else()
    set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -march=native -mtune=native")
  endif()
endif()

include(FetchContent)

FetchContent_Declare(
  poolSTL
  GIT_REPOSITORY https://github.com/alugowski/poolSTL.git
  GIT_TAG main
  GIT_SHALLOW ON)
FetchContent_MakeAvailable(poolSTL)

FetchContent_Declare(
  SFML
  GIT_REPOSITORY https://github.com/SFML/SFML.git
  GIT_TAG 3.1.0
  GIT_SHALLOW ON
  EXCLUDE_FROM_ALL
  SYSTEM)
FetchContent_MakeAvailable(SFML)

FetchContent_Declare(
    SDL3
    GIT_REPOSITORY https://github.com/libsdl-org/SDL.git
    GIT_TAG release-3.4.12
    GIT_SHALLOW ON
    EXCLUDE_FROM_ALL
    OVERRIDE_FIND_PACKAGE)
FetchContent_MakeAvailable(SDL3)

FetchContent_Declare(
    raylib
    GIT_REPOSITORY https://github.com/raysan5/raylib.git
    GIT_TAG 6.0
    GIT_SHALLOW ON
    EXCLUDE_FROM_ALL)
FetchContent_MakeAvailable(raylib)

add_library(gameoflife Grid.hpp BandExecutor.hpp DoubleBuffer.hpp Common.hpp Common.cpp)
target_link_libraries(gameoflife PUBLIC poolSTL::poolSTL)

add_executable(gameoflife-sfml main-sfml.cpp)
target_link_libraries(gameoflife-sfml PRIVATE gameoflife SFML::Graphics)

add_executable(gameoflife-sdl main-sdl.cpp)
target_link_libraries(gameoflife-sdl PRIVATE gameoflife SDL3::SDL3-static)
target_compile_definitions(gameoflife-sdl PRIVATE SDL_MAIN_USE_CALLBACKS=1) # use the callbacks instead of main()

add_executable(gameoflife-raylib main-raylib.cpp)
target_link_libraries(gameoflife-raylib PRIVATE gameoflife raylib)

add_executable(gameoflife-cli main-cli.cpp)
target_link_libraries(gameoflife-cli PRIVATE gameoflife)

add_executable(gameoflife-unittest main-unittest.cpp)
target_link_libraries(gameoflife-unittest PRIVATE gameoflife)

enable_testing()
add_test(NAME grid_unit_tests COMMAND gameoflife-unittest)