dependency-check-gradle/build.gradle.kts at main · dependency-check/dependency-check-gradle · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
import org.gradle.api.tasks.testing.logging.TestLogEvent

/*
 * This file is part of dependency-check-gradle.
 *
 * Licensed under the Apache License, Version 2.0 (the "License");
 * you may not use this file except in compliance with the License.
 * You may obtain a copy of the License at
 *
 *     http://www.apache.org/licenses/LICENSE-2.0
 *
 * Unless required by applicable law or agreed to in writing, software
 * distributed under the License is distributed on an "AS IS" BASIS,
 * WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
 * See the License for the specific language governing permissions and
 * limitations under the License.
 *
 * Copyright (c) 2015 Wei Ma. All Rights Reserved.
 */

plugins {
    id("groovy")
    id("idea")
    id("eclipse")
    id("signing")
    id("project-report")
    id("build-dashboard")
    alias(libs.plugins.gradle.plugin.publish)
}

group = "org.owasp"
version = libs.versions.odc.get()

val targetJavaVersion = 11
val gradleJavaVersion = JavaLanguageVersion.of(17)
val testToolchainVersion = providers.gradleProperty("testToolchainVersion")
    .map(JavaLanguageVersion::of)
    .orElse(gradleJavaVersion)

logger.lifecycle("Build targets $targetJavaVersion using JDK $gradleJavaVersion (test with JDK ${testToolchainVersion.get()})")

tasks.withType<JavaCompile>().configureEach {
    options.release.set(targetJavaVersion)
}
tasks.withType<GroovyCompile>().configureEach {
    // Groovy compiler does not support -release flags and ignores it
    // see https://github.com/gradle/gradle/issues/15703 and https://issues.apache.org/jira/browse/GROOVY-11105
    sourceCompatibility = targetJavaVersion.toString()
    targetCompatibility = targetJavaVersion.toString()
    options.release.set(targetJavaVersion)
}

dependencies {
    implementation(localGroovy())
    implementation(gradleApi())

    api(libs.owasp.dependencyCheck.core)
    api(libs.owasp.dependencyCheck.utils)
    api(libs.slack.webhook)

    testImplementation(platform(libs.junit.bom))
    testImplementation(platform(libs.spock.bom))
    testImplementation(libs.spock.core)
    testRuntimeOnly(libs.junit.platformSuiteEngine)
    testRuntimeOnly(libs.junit.platformLauncher)
}

tasks.withType<Test>().configureEach {
    useJUnitPlatform()
    onlyIf { !project.hasProperty("skipTests") }

    testLogging {
        events = setOf(TestLogEvent.PASSED, TestLogEvent.FAILED, TestLogEvent.SKIPPED)
    }

    javaLauncher.set(
        javaToolchains.launcherFor {
            languageVersion.set(testToolchainVersion)
        }
    )
}

publishing {
    // customise POM metadata for both the main plugin and the marker artifact based on the basic Gradle plugin metadata
    publications.withType<MavenPublication>().configureEach {
        val plugin = gradlePlugin.plugins.named("dependencyCheck").get()
        pom {
            name.set(plugin.displayName)
            description.set(plugin.description)
            url.set(gradlePlugin.website)

            licenses {
                license {
                    name.set("The Apache License, Version 2.0")
                    url.set("${gradlePlugin.vcsUrl.get()}/blob/main/LICENSE.txt")
                }
            }
            developers {
                developer {
                    id.set("jlong")
                    name.set("Jeremy Long")
                    email.set("jeremy.long@owasp.org")
                }
            }
            scm {
                url.set(gradlePlugin.vcsUrl.get())
                connection.set("scm:git:${gradlePlugin.vcsUrl.get()}.git")
                developerConnection.set("scm:git:${gradlePlugin.vcsUrl.get()}.git")
            }
        }
    }
}

signing {
    isRequired = !gradle.startParameter.taskNames.contains("publishToMavenLocal")
}

gradlePlugin {
    website.set("https://dependency-check.github.io/DependencyCheck/dependency-check-gradle")
    vcsUrl.set("https://github.com/dependency-check/dependency-check-gradle")

    plugins {
        register("dependencyCheck") {
            id = "org.owasp.dependencycheck"
            displayName = "OWASP dependency-check-gradle plugin"
            description = "A software composition analysis plugin that identifies known vulnerable dependencies used by the project."
            tags.addAll("OWASP", "dependency-check", "gradle-plugin", "software-composition-analysis", "vulnerability-detection", "security")
            implementationClass = "org.owasp.dependencycheck.gradle.DependencyCheckPlugin"
        }
    }
}

tasks.publish.get().dependsOn(tasks.publishPlugins)

defaultTasks.add("build")