build.gradle

plugins {
    id 'org.springframework.boot' version '2.7.1'
    id 'io.spring.dependency-management' version '1.0.12.RELEASE'
    id 'java-library'
    id 'maven-publish'
}

allprojects {
    apply plugin: 'org.springframework.boot'
    apply plugin: 'io.spring.dependency-management'
    apply plugin: 'java-library'
    apply plugin: 'maven-publish'

    group 'com.demkom58'
    version '0.5-SNAPSHOT'

    bootJar.enabled = false
    jar.enabled = true

    compileJava.options.encoding = "UTF-8"
    compileTestJava.options.encoding = "UTF-8"

    compileJava {
        sourceCompatibility = JavaVersion.VERSION_17
        targetCompatibility = JavaVersion.VERSION_17
    }

    dependencies {
        testImplementation group: 'org.junit.jupiter', name: 'junit-jupiter-api'
        testImplementation group: 'org.junit.jupiter', name: 'junit-jupiter-engine'
        testImplementation group: 'org.mockito', name: 'mockito-junit-jupiter'
    }

    test {
        useJUnitPlatform()
    }

    task sourceJar(type: Jar) {
        from sourceSets.main.allJava
        archiveClassifier = "sources"
    }

    task install(dependsOn: 'publishToMavenLocal')

    publishing {
        publications {
            maven(MavenPublication) {
                from components.java

                artifact sourceJar
            }
        }

        repositories {
            maven {
                name = "GitHubPackages"
                url = uri("https://maven.pkg.github.com/demkom58/springram")
                credentials {
                    username = project.findProperty("gpr.user") ?: System.getenv("USERNAME")
                    password = project.findProperty("gpr.key") ?: System.getenv("TOKEN")
                }
            }
        }
    }

}