ViaRewind/build.gradle.kts at master · ViaVersion/ViaRewind · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
import de.florianreuth.baseproject.*

plugins {
    `java-library`
    id("io.papermc.hangar-publish-plugin")
    id("com.modrinth.minotaur")
    id("de.florianreuth.baseproject")
}

allprojects {

    setupProject()
    setupViaPublishing()

    repositories {
        mavenCentral()
        maven("https://repo.viaversion.com")
        maven("https://repo.papermc.io/repository/maven-public")
        maven("https://maven.fabricmc.net")
    }

}

subprojects {

    dependencies {
        compileOnly("com.viaversion:viaversion:5.7.2")
        compileOnly("com.viaversion:viabackwards:5.7.2")
    }

    tasks {
        processResources {
            val projectVersion = project.version
            val projectDescription = project.description
            filesMatching(listOf("plugin.yml", "fabric.mod.json", "META-INF/sponge_plugins.json")) {
                expand(mapOf("version" to projectVersion, "description" to projectDescription))
            }
        }
    }

}

base {
    archivesName.set("ViaRewind")
}

val shade = configureShadedDependencies(false) // Only shade, don't add them as dependency

dependencies {
    subprojects.forEach {
        shade(it)
    }
}

tasks {
    jar {
        manifest {
            attributes("paperweight-mappings-namespace" to "mojang")
        }
    }
}

val branch = branchName()
val baseVersion = version as String
val isRelease = !baseVersion.contains('-')
val isMainBranch = branch == "master"
if (!isRelease || isMainBranch) { // Only publish releases from the main branch
    val suffixedVersion = if (isRelease) baseVersion else baseVersion + "+" + System.getenv("GITHUB_RUN_NUMBER")
    val changelogContent = if (isRelease) {
        "See [GitHub](https://github.com/ViaVersion/ViaRewind) for release notes."
    } else {
        val commitHash = latestCommitHash()
        "[$commitHash](https://github.com/ViaVersion/ViaRewind/commit/$commitHash) ${latestCommitMessage()}"
    }

    modrinth {
        val mcVersions: List<String> = (property("minecraft_versions") as String)
            .split(",")
            .map { it.trim() }
        token.set(System.getenv("MODRINTH_TOKEN"))
        projectId.set("viarewind")
        versionType.set(if (isRelease) "release" else if (isMainBranch) "beta" else "alpha")
        versionNumber.set(suffixedVersion)
        versionName.set(suffixedVersion)
        changelog.set(changelogContent)
        uploadFile.set(tasks.jar.flatMap { it.archiveFile })
        gameVersions.set(mcVersions)
        loaders.add("fabric")
        loaders.add("paper")
        loaders.add("folia")
        loaders.add("velocity")
        autoAddDependsOn.set(false)
        detectLoaders.set(false)
        dependencies {
            required.project("viaversion")
            required.project("viabackwards")
            optional.project("viafabric")
        }
    }
    tasks.modrinth {
        notCompatibleWithConfigurationCache("")
    }

    hangarPublish {
        publications.register("plugin") {
            version.set(suffixedVersion)
            id.set("ViaRewind")
            channel.set(if (isRelease) "Release" else if (isMainBranch) "Snapshot" else "Alpha")
            changelog.set(changelogContent)
            apiKey.set(System.getenv("HANGAR_TOKEN"))
            platforms {
                paper {
                    jar.set(tasks.jar.flatMap { it.archiveFile })
                    platformVersions.set(listOf(property("minecraft_version_range") as String))
                    dependencies {
                        hangar("ViaVersion") {
                            required = true
                        }
                        hangar("ViaBackwards") {
                            required = true
                        }
                    }
                }
                velocity {
                    jar.set(tasks.jar.flatMap { it.archiveFile })
                    platformVersions.set(listOf(property("velocity_version") as String))
                    dependencies {
                        hangar("ViaVersion") {
                            required = true
                        }
                        hangar("ViaBackwards") {
                            required = true
                        }
                    }
                }
            }
        }
    }
    tasks.named("publishPluginPublicationToHangar") {
        notCompatibleWithConfigurationCache("")
    }
}