build.gradle

plugins {
	id 'net.fabricmc.fabric-loom' version '1.15.+'
	id "com.modrinth.minotaur" version "2.+"
	id 'maven-publish'
}

base {
	archivesName = project.archives_base_name
}
group = project.maven_group

if (System.getenv("CI") != null) {
	if (System.getenv("RELEASE") != null) {
		version = project.mod_version
	} else {
		version = project.mod_version + "-dev.build." + System.getenv("GITHUB_RUN_NUMBER")
	}
} else {
	version = project.mod_version + "-dev.local"
}

version = version + "+" + project.minecraft_version

loom {
	runs {
		datagen {
			server()
			name = "Data Generation"
			runDir = "build/datagen"
			vmArg("-Dfabric-api.datagen")
			vmArg("-Dfabric-api.datagen.id=polydecorations")
			vmArg("-Dfabric-api.datagen.output-dir=${file("src/main/generated")}")
		}
	}
	accessWidenerPath = file("src/main/resources/polydecorations.accesswidener")

}


sourceSets {
	main {
		resources {
			srcDirs += [
					"src/main/generated"
			]
		}
	}
}

repositories {
	// Add repositories to retrieve artifacts from in here.
	// You should only use this when depending on other mods because
	// Loom adds the essential maven repositories to download Minecraft and libraries from automatically.
	// See https://docs.gradle.org/current/userguide/declaring_repositories.html
	// for more information about repositories.
	maven { url 'https://maven.nucleoid.xyz/releases/' }
	maven { url 'https://kneelawk.com/maven' }
	maven { url "https://maven.alexiil.uk/" }
	maven { url "https://api.modrinth.com/maven/" }
	maven { url = "https://jitpack.io" }
	maven { url 'https://oss.sonatype.org/content/repositories/snapshots' }

	mavenLocal()
}

dependencies {
	// To change the versions see the gradle.properties file
	minecraft "com.mojang:minecraft:${project.minecraft_version}"
	implementation "net.fabricmc:fabric-loader:${project.loader_version}"

	// Fabric API. This is technically optional, but you probably want it anyway.
	implementation "net.fabricmc.fabric-api:fabric-api:${project.fabric_api_version}"

	implementation 'eu.pb4:polymer-core:0.16.0-pre.4+26.1'
	implementation 'eu.pb4:polymer-blocks:0.16.0-pre.4+26.1'
	implementation 'eu.pb4:polymer-resource-pack:0.16.0-pre.4+26.1'
	implementation 'eu.pb4:polymer-resource-pack-extras:0.16.0-pre.4+26.1'
	implementation 'eu.pb4:polymer-autohost:0.16.0-pre.4+26.1'
	implementation 'eu.pb4:polymer-virtual-entity:0.16.0-pre.4+26.1'
	implementation include('eu.pb4:common-protection-api:2.0.0')
	implementation include('eu.pb4:sgui:2.0.0+26.1')
	implementation include('eu.pb4:map-canvas-api:0.8.0+26.1')
	implementation include('eu.pb4:factorytools:0.10.0-pre.2+26.1')
	implementation include('nl.theepicblock:resource-locator-api:0.7.0-patbox+26.1')

	// Temp hack to allow development
	//implementation include('com.kneelawk:graphlib:1.99.99+1.20.local')
	//implementation include('alexiil.mc.lib:libnetworkstack-base:0.11.0-aaa.patbox')

	compileOnly 'eu.pb4:polydex:1.9.2+26.1-rc-3'

	// Uncomment the following line to enable the deprecated Fabric API modules. 
	// These are included in the Fabric API production distribution and allow you to update your mod to the latest modules at a later more convenient time.

	// implementation "net.fabricmc.fabric-api:fabric-api-deprecated:${project.fabric_version}"
}

processResources {
	inputs.property "version", project.version

	filesMatching("fabric.mod.json") {
		expand "version": project.version
	}
}

tasks.withType(JavaCompile).configureEach {
	// Minecraft 1.18 (1.18-pre2) upwards uses Java 17.
	it.options.release = 25
}

java {
	// Loom will automatically attach sourcesJar to a RemapSourcesJar task and to the "build" task
	// if it is present.
	// If you remove this line, sources will not be generated.
	withSourcesJar()
}

jar {
	from("LICENSE") {
		rename { "${it}_${project.archives_base_name}"}
	}
}

// configure the maven publication
publishing {
	publications {
		mavenJava(MavenPublication) {
			from components.java
		}
	}

	// See https://docs.gradle.org/current/userguide/publishing_maven.html for information on how to set up publishing.
	repositories {
		// Add repositories to publish to here.
		// Notice: This block does NOT have the same function as the block in the top level.
		// The repositories here will be used for publishing your artifact, not for
		// retrieving dependencies.
	}
}

if (System.getenv("MODRINTH")) {
	modrinth {
		token = System.getenv("MODRINTH")
		projectId = '5710VC7f'// The ID of your modrinth project, slugs will not work.
		versionNumber = "" + version // The version of the mod to upload.
		versionType = "release"
		uploadFile = jar // This links to a task that builds your mod jar and sets "uploadFile" to the mod jar.
		gameVersions = [((String) project.minecraft_version)]
		changelog = System.getenv("CHANGELOG")
		loaders = ["fabric"]

		dependencies {
			required.project "polymer"
			optional.project "armorstandeditor"
		}
	}

	jar {
		finalizedBy project.tasks.modrinth
	}
}