MergeTool/build.gradle at master · ForgeForce/MergeTool · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
plugins {
    id 'java'
    id 'eclipse'
    id 'maven-publish'
    id 'org.cadixdev.licenser' version '0.6.1'
    id 'com.github.johnrengelman.shadow' version '7.1.2'
    id 'com.github.ben-manes.versions' version '0.42.0'
    id 'net.minecraftforge.gradleutils' version '2.+'
}

group = 'net.minecraftforge'
version = gradleutils.getTagOffsetVersion()
println('Version: ' + version)

repositories {
    mavenCentral()
    maven { url = 'https://maven.minecraftforge.net' }
}

license {
    header project.file('LICENSE-header.txt')
    include 'net/minecraftforge/mergetool/**/*.java'
    newLine false
}

sourceSets {
    cpwFML
    forgeFML
    forgeAPI
}

java {
    toolchain.languageVersion = JavaLanguageVersion.of(8)
    withSourcesJar()
}

jar {
    manifest.attributes('Main-Class': 'net.minecraftforge.mergetool.ConsoleMerger')
    manifest.attributes('Implementation-Version': project.version)
    from sourceSets.cpwFML.output
    from sourceSets.forgeFML.output
    from sourceSets.forgeAPI.output
}
shadowJar {
    classifier 'fatjar'
}
sourcesJar {
    from sourceSets.cpwFML.allSource
    from sourceSets.forgeFML.allSource
    from sourceSets.forgeAPI.allSource
}
task cpwFML(type: Jar) {
    classifier 'cpw'
    from sourceSets.cpwFML.output
}
task forgeFML(type: Jar) {
    classifier 'forge'
    from sourceSets.forgeFML.output
}
task forgeAPI(type: Jar) {
    classifier 'api'
    from sourceSets.forgeAPI.output
}

dependencies {
    implementation 'org.ow2.asm:asm:9.5'
    implementation 'org.ow2.asm:asm-tree:9.5'
    implementation 'org.ow2.asm:asm-util:9.5'
    implementation 'net.sf.jopt-simple:jopt-simple:5.0.4'
    implementation 'net.minecraftforge:srgutils:0.4.15'

    implementation sourceSets.cpwFML.output
    implementation sourceSets.forgeFML.output
    implementation sourceSets.forgeAPI.output
}

artifacts {
    archives shadowJar
    archives cpwFML
    archives forgeFML
    archives forgeAPI
}

publishing {
    publications.create("mavenJava", MavenPublication) {
        from components.java
        artifact cpwFML
        artifact forgeFML
        artifact forgeAPI

        pom {
            name = 'MergeTool'
            description = 'Merges two jar files together, useful for rebuilding Retroguard stripped jars.'
            url = 'https://github.com/MinecraftForge/MergeTool'
            scm {
                url = 'https://github.com/MinecraftForge/MergeTool'
                connection = 'scm:git:git://github.com/MinecraftForge/MergeTool.git'
                developerConnection = 'scm:git:[email protected]:MinecraftForge/MergeTool.git'
            }
            issueManagement {
                system = 'github'
                url = 'https://github.com/MinecraftForge/MergeTool/issues'
            }

            licenses {
                license {
                    name = 'LGPLv2.1'
                    url = 'https://www.gnu.org/licenses/old-licenses/lgpl-2.1.txt'
                }
            }

            developers {
                developer {
                    id = 'LexManos'
                    name = 'Lex Manos'
                }
            }
        }
    }
    repositories {
        maven gradleutils.getPublishingForgeMaven()
    }
}