expediagroup-java-sdk/build.gradle at main · ExpediaGroup/expediagroup-java-sdk · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
import org.jetbrains.kotlin.gradle.plugin.KotlinBasePluginWrapper
import org.jetbrains.kotlin.gradle.tasks.KotlinCompile
import java.time.Duration

plugins {
    id 'java'
    id 'org.jetbrains.kotlin.jvm' version '2.2.10' apply false
    id "org.jlleitschuh.gradle.ktlint" version "12.3.0" apply false
    id 'org.jetbrains.kotlinx.kover' version "0.9.1" apply false
    id 'io.github.gradle-nexus.publish-plugin' version '2.0.0'
}

group = project.property("GROUP_ID")

apply from: "$rootDir/gradle-tasks/publish-snapshot.gradle"

nexusPublishing {
    repositories {
        sonatype {
            nexusUrl.set(uri("https://ossrh-staging-api.central.sonatype.com/service/local/"))
            snapshotRepositoryUrl.set(uri("https://central.sonatype.com/repository/maven-snapshots/"))
            username = System.getenv("SONATYPE_USERNAME")
            password = System.getenv("SONATYPE_PASSWORD")
        }
    }

    transitionCheckOptions {
        maxRetries = 60
        delayBetween = Duration.ofMillis(5000)
    }
}

subprojects {
    /* Shared plugins across all modules */
    apply plugin: 'java'
    apply plugin: 'org.jetbrains.kotlin.jvm'
    apply plugin: 'org.jlleitschuh.gradle.ktlint'
    apply plugin: 'org.jetbrains.kotlinx.kover'

    /* Shared repositories across all modules */
    repositories {
        mavenCentral()
        mavenLocal()
        maven {
            url "https://oss.sonatype.org/content/repositories/snapshots/"
        }
    }

    plugins.withId("org.jetbrains.kotlin.jvm") {
        kotlin {
            jvmToolchain(8)
        }
    }

    plugins.withType(KotlinBasePluginWrapper).configureEach {
        tasks.withType(KotlinCompile).configureEach {
            kotlinOptions {
                jvmTarget = "1.8"
            }
        }
    }

    java {
        withSourcesJar()
        withJavadocJar()
        sourceCompatibility = JavaVersion.VERSION_1_8
        targetCompatibility = JavaVersion.VERSION_1_8

        toolchain {
            languageVersion.set(JavaLanguageVersion.of(8))
        }
    }

    ktlint {
        debug = true
        version = "1.5.0"
        verbose = true

        additionalEditorconfig = [
            "max_line_length"     : "120",
            "indent_style"        : "space",
            "indent_size"         : "4",
            "insert_final_newline": "true",
            "end_of_line"         : "lf",
        ]

        filter {
            exclude("**/testservice/**")
        }
    }
}