fray/flake.nix at main · DistCompiler/fray · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
{
  description = "Fray Flake Configuration";

  inputs = {
    flake-compat.url = "https://flakehub.com/f/edolstra/flake-compat/1.tar.gz";
    nixpkgs.url = "https://flakehub.com/f/NixOS/nixpkgs/0.1.*.tar.gz";
    gradle2nix.url = "github:tadfisher/gradle2nix/v2";
  };
  outputs =
    { self
    , nixpkgs
    , gradle2nix
    , flake-compat
    ,
    }:
    let
      supportedSystems = [ "x86_64-linux" "aarch64-darwin" ];
      forEachSupportedSystem = f:
        nixpkgs.lib.genAttrs supportedSystems (system:
          f {
            pkgs = import nixpkgs {
              inherit system;
              overlays = [ self.overlays.default ];
            };
          });
    in
    {
      overlays.default = final: prev: {
        jdk = prev.javaPackages.compiler.openjdk25;
        java = prev.javaPackages.compiler.openjdk25;
      };

      packages = forEachSupportedSystem (
        { pkgs }:
        let
          commonPackages = with pkgs; [
            gcc
            cmake
            javaPackages.compiler.openjdk25
            jdk11
          ];

          commonEnv = ''
            export CC="${pkgs.gcc}/bin/gcc"
            export CXX="${pkgs.gcc}/bin/g++"
            export JDK11="${pkgs.jdk11.home}"
            export JDK25="${pkgs.javaPackages.compiler.openjdk25.home}"
            export JRE="${pkgs.javaPackages.compiler.openjdk25.home}"
            export JAVA_HOME="${pkgs.javaPackages.compiler.openjdk25.home}"
            ${pkgs.lib.optionalString pkgs.stdenv.isLinux ''
              export JETBRAINS_JDK_HOME="${pkgs.jetbrains.jdk.home}"
            ''}
          '';

          project =
            (gradle2nix.builders.${pkgs.system}.buildGradlePackage {
              pname = "fray";
              version = "0.7.4-SNAPSHOT";
              src = ./.;
              lockFile = ./gradle.lock;
              gradleBuildFlags = [
                "-Porg.gradle.java.installations.paths=${pkgs.jdk11.home},${pkgs.javaPackages.compiler.openjdk25.home}"
                "build"
                "-x"
                "test"
                "-x"
                "check"
              ];
              buildInputs = commonPackages;
              preBuild = ''
                ${commonEnv}
                java -version
                sed -i '/include("plugins/d' settings.gradle.kts
                sed -i '/include("integration-test")/d' settings.gradle.kts
              '';
            }).overrideAttrs (_: prev: {
              gradleFlags = pkgs.lib.lists.remove "--console=plain" prev.gradleFlags;
              installPhase = ''
                runHook preInstall
                mkdir -p $out/libs
                mkdir -p $out/bin
                cp core/build/libs/*.jar $out/libs
                cp instrumentation/agent/build/libs/*.jar $out/libs
                cp -r instrumentation/jdk/build/java-inst $out/
                cp -r jvmti/build/native-libs $out/
                gradle --no-daemon -Pfray.installDir=$out/ genRunner
                cp bin/fray $out/bin/
                runHook postInstall
              '';
            });
          dockerImage = pkgs.dockerTools.buildImage {
            name = "fray";
            tag = "latest";
            copyToRoot = pkgs.runCommand "image-root" {}
              ''
              mkdir -p $out/opt
              ln -s ${project} $out/opt/fray
              '';
          };
        in
        {
          default = project;
          dockerImage = dockerImage;
        }
      );

      devShells = forEachSupportedSystem ({ pkgs }: {
        default = pkgs.mkShell {
          packages = (with pkgs; [
            gcc
            cmake
            javaPackages.compiler.openjdk25
            jdk11
          ]) ++ pkgs.lib.optionals (pkgs.stdenv.isLinux) [
            pkgs.jetbrains.jdk
          ];
          shellHook = ''
            export CC="${pkgs.gcc}/bin/gcc"
            export CXX="${pkgs.gcc}/bin/g++"
            export JDK11="${pkgs.jdk11.home}"
            export JDK21="${pkgs.jdk21.home}"
            export JDK25="${pkgs.javaPackages.compiler.openjdk25.home}"
            export JRE="${pkgs.javaPackages.compiler.openjdk25.home}"
            export JAVA_HOME="${pkgs.javaPackages.compiler.openjdk25.home}"
            ${pkgs.lib.optionalString pkgs.stdenv.isLinux ''
              export JETBRAINS_JDK_HOME="${pkgs.jetbrains.jdk.home}"
            ''}
          '';
        };
      });
    };
}