DiligentTools/TextureLoader/CMakeLists.txt at master · DiligentGraphics/DiligentTools · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
cmake_minimum_required (VERSION 3.10)

project(Diligent-TextureLoader CXX)

set(INCLUDE
    include/dxgiformat.h
    include/pch.h
    include/TextureLoaderImpl.hpp
)

set(INTERFACE
    interface/JPEGCodec.h
    interface/PNGCodec.h
    interface/SGILoader.h
    interface/BCTools.h
    interface/Image.h
    interface/TextureLoader.h
    interface/TextureUtilities.h
)

set(SOURCE
    src/BCTools.cpp
    src/DDSLoader.cpp
    src/JPEGCodec.c
    src/Image.cpp
    src/KTXLoader.cpp
    src/SGILoader.cpp
    src/PNGCodec.c
    src/STBImpl.cpp
    src/TextureLoaderImpl.cpp
    src/TextureUtilities.cpp
)

add_library(Diligent-TextureLoader STATIC ${SOURCE} ${INCLUDE} ${INTERFACE})
set_common_target_properties(Diligent-TextureLoader)

set_property(SOURCE src/PNGCodec.c src/Image.cpp
APPEND PROPERTY INCLUDE_DIRECTORIES
    "${CMAKE_CURRENT_SOURCE_DIR}/../ThirdParty/libpng" # png_static target does not define any public include directories
    "${CMAKE_CURRENT_BINARY_DIR}/../ThirdParty/libpng" # pnglibconf.h is generated in the binary directory
)

target_include_directories(Diligent-TextureLoader
PUBLIC
    interface
PRIVATE
    include
)

source_group("source" FILES ${SOURCE})
source_group("include" FILES ${INCLUDE})
source_group("interface" FILES ${INTERFACE})

target_link_libraries(Diligent-TextureLoader
PRIVATE
    Diligent-BuildSettings
    Diligent-Common
    Diligent-PlatformInterface
    Diligent-GraphicsEngineInterface
    Diligent-GraphicsAccessories
    Diligent-GraphicsTools
    PNG::PNG
    TIFF::TIFF
    ZLIB::ZLIB
)

if (NOT DILIGENT_EXTERNAL_LIBJPEG)
    target_link_libraries(Diligent-TextureLoader
    PRIVATE
        JPEG::JPEG
    )
else()
    target_link_libraries(Diligent-TextureLoader
    PRIVATE
        ${DILIGENT_EXTERNAL_LIBJPEG}
    )
endif()

set_target_properties(Diligent-TextureLoader PROPERTIES
    FOLDER DiligentTools
)

if(DILIGENT_INSTALL_TOOLS)
    install_tools_lib(Diligent-TextureLoader)
endif()